*In this article, you will learn how to build an Excel IF statement for different types of values as well as how to create multiple IF statements.*

IF is one of the most popular and useful functions in Excel. Generally, you use an IF statement to test a condition and to return one value if the condition is met, and another value if the condition is not met.

In this tutorial, we are going to learn the syntax and common usages of the Excel IF function, and then take a closer look at formula examples that will hopefully prove helpful to both beginners and experienced users.

## IF function in Excel

IF is one of logical functions that evaluates a certain condition and returns one value if the condition is TRUE, and another value if the condition is FALSE.

The syntax of the IF function is as follows:

IF(logical_test, [value_if_true], [value_if_false])

As you see, IF takes a total of 3 arguments, but only the first one is obligatory, the other two are optional.

**Logical_test** (required) - the condition to test. Can be evaluated as either TRUE or FALSE.

**Value_if_true** (optional) - the value to return when the logical test evaluates to TRUE, i.e. the condition is met. If omitted, the *value_if_false* argument must be defined.

**Value_if_false** (optional) - the value to return when the logical test evaluates to FALSE, i.e. the condition is not met. If omitted, the *value_if_true* argument must be set.

## Basic IF formula in Excel

To create a simple *If then* statement in Excel, this is what you need to do:

- For
*logical_test*, write an expression that returns either TRUE or FALSE. For this, you'd normally use one of the logical operators. - For
*value_if_true*, specify what to return when the logical test evaluates to TRUE. - For
*value_if_false*, specify what to return when the logical test evaluates to FALSE. Though this argument is optional, we recommend always configuring it to avoid unexpected results. For the detailed explanation, please see Excel IF: things to know.

As an example, let's write a very simple IF formula that checks a value in cell A2 and returns "Good" if the value is greater than 80, "Bad" otherwise:

`=IF(B2>80, "Good", "Bad")`

This formula goes to C2, and then is copied down through C7:

In case you wish to return a value only when the condition is met (or not met), otherwise - nothing, then use an empty string ("") for the "undefined" argument. For example:

`=IF(B2>80, "Good", "")`

This formula will return "Good" if the value in A2 is greater than 80, a blank cell otherwise:

## Excel If then formula: things to know

Though the last two parameters of the IF function are optional, your formula may produce unexpected results if you don't know the underlying logic.

### If value_if_true is omitted

If the 2^{nd} argument of your Excel IF formula is omitted (i.e. there are two consecutive commas after the logical test), you'll get zero (0) when the condition is met, which makes no sense in most cases. Here is an example of such a formula:

`=IF(B2>80, , "Bad")`

To return a blank cell instead, supply an empty string ("") for the second parameter, like this:

`=IF(B2>80, "", "Bad")`

The screenshot below demonstrates the difference:

### If value_if_false is omitted

Omitting the 3^{rd} parameter of IF will produce the following results when the logical test evaluates to FALSE.

If there is just a closing bracket after *value_if_true*, the IF function will return the logical value FALSE. Quite unexpected, isn't it? Here is an example of such a formula:

`=IF(B2>80, "Good")`

Typing a comma after the *value_if_true* argument will force Excel to return 0, which doesn't make much sense either:

`=IF(B2>80, "Good",)`

The most reasonable approach is using a zero-length string ("") to get a blank cell when the condition is not met:

`=IF(B2>80, "Good", "")`

Tip. To return a logical value when the specified condition is met or not met, supply TRUE for *value_if_true* and FALSE for *value_if_false*. For the results to be Boolean values that other Excel functions can recognize, don't enclose TRUE and FALSE in double quotes as this will turn them into normal text values.

## Using IF function in Excel - formula examples

Now that you are familiar with the IF function's syntax, let's look at some formula examples and learn how to use *If then* statements in real-life scenarios.

### Excel IF function with numbers

To build an IF statement for numbers, use logical operators such as:

- Equal to (=)
- Not equal to (<>)
- Greater than (>)
- Greater than or equal to (>=)
- Less than (<)
- Less than or equal to (<=)

Above, you have already seen an example of such a formula that checks if a number is greater than a given number.

And here's a formula that checks if a cell contains a **negative number**:

`=IF(B2<0, "Invalid", "")`

For negative numbers (which are less than 0), the formula returns "Invalid"; for zeros and positive numbers - a blank cell.

### Excel IF function with text

Commonly, you write an IF statement for text values using either "equal to" or "not equal to" operator.

For example, the following formula checks the *Delivery Status* in B2 to determine whether an action is required or not:

`=IF(B2="delivered", "No", "Yes")`

Translated into plain English, the formula says: return "No" if B2 is equal to "delivered", "Yes" otherwise.

Another way to achieve the same result is to use the "not equal to" operator and swap the *value_if_true* and *value_if_false* values:

`=IF(C2<>"delivered", "Yes", "No")`

Notes:

- When using text values for IF's parameters, remember to always enclose them in
**double quotes**. - Like most other Excel functions,
**IF is case-insensitive by default**. In the above example, it does not differentiate between "delivered", "Delivered", and "DELIVERED".

### Case-sensitive IF statement for text values

To treat uppercase and lowercase letters as different characters, use IF in combination with the case-sensitive EXACT function.

For example, to return "No" only when B2 contains "DELIVERED" (the uppercase), you'd use this formula:

`=IF(EXACT(B2,"DELIVERED"), "No", "Yes")`

### If cell contains partial text

In situation when you want to base the condition on **partial match** rather than exact match, an immediate solution that comes to mind is using wildcards in the logical test. However, this simple and obvious approach won't work. Many functions accept wildcards, but regrettably IF is not one of them.

A working solution is to use IF in combination with ISNUMBER and SEARCH (case-insensitive) or FIND (case-sensitive).

For example, in case "No" action is required both for "Delivered" and "Out for delivery" items, the following formula will work a treat:

`=IF(ISNUMBER(SEARCH("deliv", B2)), "No", "Yes")`

For more information, please see:

- Excel IF statement for partial text match
- If cell contains then

### Excel IF statement with dates

At first sight, it may seem that IF formulas for dates are akin to IF statements for numeric and text values. Regrettably, it is not so. Unlike many other functions, IF does recognize dates in logical tests and interprets them as mere text strings. In other words, you cannot supply a date in the form of "1/1/2020" or ">1/1/2020". To make the IF function recognize a date, you need to wrap it in the DATEVALUE function.

For example, here's how you can check if a given date is greater than another date:

`=IF(B2>DATEVALUE("7/18/2022"), "Coming soon", "Completed")`

This formula evaluates the dates in column B and returns "Coming soon" if a game is scheduled for 18-Jul-2022 or later, "Completed" for a prior date.

Of course, there is nothing that would prevent you from entering the target date in a predefined cell (say E2) and referring to that cell. Just remember to lock the cell address with the $ sign to make it an absolute reference. For instance:

`=IF(B2>$E$2, "Coming soon", "Completed")`

To compare a date with the *current date*, use the TODAY() function. For example:

`=IF(B2>TODAY(), "Coming soon", "Completed")`

### Excel IF statement for blanks and non-blanks

If you are looking to somehow mark your data based on a certain cell(s) being empty or not empty, you can either:

- Use the IF function together with ISBLANK, or
- Use the logical expressions ="" (equal to blank) or <>"" (not equal to blank).

The table below explains the difference between these two approaches with formula examples.

Logical test | Description | Formula Example | |

Blank cells | ="" | Evaluates to TRUE if a cell is visually empty, even if it contains a Otherwise, evaluates to FALSE. | =IF(A1="", 0, 1)Returns 0 if A1 is visually blank. Otherwise returns 1. If A1 contains an empty string (""), the formula returns 0. |

ISBLANK() | Evaluates to TRUE is a cell contains Otherwise, evaluates to FALSE. | =IF(Returns 0 if A1 is absolutely empty, 1 otherwise. If A1 contains an empty string (""), the formula returns 1. | |

Non-blank cells | <>"" | Evaluates to TRUE if a cell contains some data. Otherwise, evaluates to FALSE. Cells with | =IF(Returns 1 if A1 is non-blank; 0 otherwise. If A1 contains an empty string, the formula returns 0. |

ISBLANK() | Evaluates to TRUE if a cell is not empty. Otherwise, evaluates to FALSE. Cells with | =IF(Works the same as the above formula, but returns 1 if A1 contains an empty string. |

And now, let's see blank and non-blank IF statements in action. Suppose you have a date in column B only if a game has already been played. To label the completed games, use one of these formulas:

`=IF(B2="", "", "Completed")`

`=IF(ISBLANK(B2), "", "Completed")`

`=IF($B2<>"", "Completed", "")`

`=IF(ISBLANK($B2)=FALSE, "Completed", "")`

In case the tested cells have no zero-length strings, all the formulas will return exactly the same results:

### Check if two cells are the same

To create a formula that checks if two cells match, compare the cells by using the equals sign (=) in the logical test of IF. For example:

`=IF(B2=C2, "Same score", "")`

To check if the two cells contain same text including the letter case, make your IF formula case-sensitive with the help of the EXACT function.

For instance, to compare the passwords in A2 and B2, and returns "Match" if the two strings are exactly the same, "Do not match" otherwise, the formula is:

`=IF(EXACT(A2, B2), "Match", "Don't match")`

### IF then formula to run another formula

In all of the previous examples, an Excel IF statement returned values. But it can also perform a certain calculation or execute another formula when a specific condition is met or not met. For this, embed another function or arithmetic expression in the *value_if_true* and/or *value_if_false* arguments.

For example, if B2 is greater than 80, we'll have it multiplied by 7%, otherwise by 3%:

`=IF(B2>80, B2*7%, B2*3%)`

## Multiple IF statements in Excel

In essence, there are two ways to write multiple IF statements in Excel:

- Nesting several IF functions one into another
- Using the AND or OR function in the logical test

### Nested IF statement

Nested IF functions let you place multiple IF statements in the same cell, i.e. test multiple conditions within one formula and return different values depending on the results of those tests.

Assume your goal is to assign different bonuses based on the score:

- Over 90 - 10%
- 90 to 81 - 7%
- 80 to 70 - 5%
- Less than 70 - 3%

To accomplish the task, you write 3 separate IF functions and nest them one into another like this:

`=IF(B2>90, 10%, IF(B2>=81, 7%, IF(B2>=70, 5%, 3%)))`

For more formula examples, please see:

### Excel IF statement with multiple conditions

To evaluate several conditions with the AND or OR logic, embed the corresponding function in the logical test:

For example, to return "Pass" if both scores in B2 and C2 are higher than 80, the formula is:

`=IF(AND(B2>80, C2>80), "Pass", "Fail")`

To get "Pass" if either score is higher than 80, the formula is:

`=IF(OR(B2>80, C2>80), "Pass", "Fail")`

For full details, please visit:

## If error in Excel

Starting from Excel 2007, we have a special function, named IFERROR, to check formulas for errors. In Excel 2013 and higher, there is also the IFNA function to handle #N/A errors.

And still, there may be some circumstances when using the IF function together with ISERROR or ISNA is a better solution. Basically, IF ISERROR is the formula to use when you want to return something if error and something else if no error. The IFERROR function is unable to do that as it always returns the result of the main formula if it isn't an error.

For example, to compare each score in column B against the top 3 scores in E2:E4, and return "Yes" if a match is found, "No" otherwise, you enter this formula in C2, and then copy it down through C7:

`=IF(ISERROR(MATCH(B2, $E$2:$E$4, 0)), "No", "Yes" )`

For more information, please see IF ISERROR formula in Excel.

Hopefully, our examples have helped you get a grasp of the Excel IF basics. I thank you for reading and hope to see you on our blog next week!

## Practice workbook

Excel IF statement - formula examples (.xlsx file)

## You may also be interested in

- Excel IF function with multiple criteria
- IF VLOOKUP in Excel
- If cell contains then count, sum, highlight, copy or delete
- Excel IF statement between two numbers or dates
- Check if two cells match or multiple cells are equal